File Coverage

blib/lib/DBIx/DataModel/Schema/ResultAs/Hashref.pm

Criterion	Covered	Total	%
statement	37	37	100.0
branch	4	6	66.6
condition	6	7	85.7
subroutine	8	8	100.0
pod	1	2	50.0
total	56	60	93.3

#----------------------------------------------------------------------
package DBIx::DataModel::Schema::ResultAs::Hashref;
#----------------------------------------------------------------------
use warnings;
use strict;
use Carp::Clan       qw[^(DBIx::DataModel::|SQL::Abstract)];

use parent 'DBIx::DataModel::Schema::ResultAs';

use namespace::clean;

sub new {
  my $class = shift;

  my $self;

  if ((ref $_[0] || '') eq 'CODE') {
    $self = {make_key => shift};
    !@_ or croak "-result_as => [hashref => sub {...}] : improper other args after sub{}";
  }
  else {
    $self = {cols => \@_};
  }

  return bless $self, $class;
}


sub get_result {
  my ($self, $statement) = @_;

  my $make_key = $self->{make_key} || do {
    my @cols = @{$self->{cols}};
    @cols = $statement->meta_source->primary_key              if !@cols;
    croak "-result_as=>'hashref' impossible: no primary key"  if !@cols;
    sub {my $row = shift; map {defined $row->{$_} ? $row->{$_} : ''} @cols};
  };

  $statement->execute;

  my %hash;
  while (my $row = $statement->next) {
    my @key = $make_key->($row);
    my $last_key_item = pop @key;
    my $node          = \%hash;
    $node = $node->{$_} ||= {} foreach @key;
    $node->{$last_key_item} = $row;
  }
  $statement->finish;
  return \%hash;
}


1;

__END__