File Coverage

blib/lib/DBIx/Class/Storage/TxnEndHook.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	4	4	100.0
condition	2	3	66.6
subroutine	11	11	100.0
pod	4	4	100.0
total	60	61	98.3

package DBIx::Class::Storage::TxnEndHook;
use 5.008005;
use strict;
use warnings;

use Try::Tiny;
use base 'DBIx::Class::Storage';

__PACKAGE__->mk_group_accessors(simple => qw/_hooks/);

our $VERSION = "0.01";

sub new {
    my $self = shift->next::method(@_);
    $self->_hooks([]);
    $self;
}

sub add_txn_end_hook {
    my ($self, $hook) = @_;

    unless ( $self->transaction_depth > 0 ) {
        $self->throw_exception('only can call add_txn_end_hook in transaction');
    }

    push @{ $self->_hooks }, $hook;
}

sub txn_commit {
    my $self = shift;
    my $is_last_txn = $self->transaction_depth == 1;
    my @ret = $self->next::method(@_);

    if ( $is_last_txn && @{ $self->_hooks } ) {
        try {
            while ( my $hook = shift @{ $self->_hooks } ) {
                $hook->();
            }
        }
        catch {
            $self->_hooks([]);
            warn $_;
        };
    }

    @ret;
}

sub txn_rollback {
    my $self = shift;
    my @ret = $self->next::method(@_);
    $self->_hooks([]);
    @ret;
}

1;
__END__