File Coverage

blib/lib/DBIx/Class/Schema/Loader/Dynamic.pm

Criterion	Covered	Total	%
statement	61	64	95.3
branch	5	10	50.0
condition	4	9	44.4
subroutine	13	18	72.2
pod	1	1	100.0
total	84	102	82.3

package DBIx::Class::Schema::Loader::Dynamic;

use strict;
use warnings;

use base qw/DBIx::Class::Schema::Loader::DBI/;
use mro 'c3';
use Data::Dumper;

our $VERSION = '1.05';

sub new {
    my ($self, %args) = @_;
    my $class = ref $self || $self;

    $args{dump_directory}    ||= '/die/if/I/get/used';
    $args{left_base_classes} ||= ['DBIx::Class::Core'];

    my $new = $self->next::method(%args);

    # The loader 'factory' returns a more engine-specific subclass, e.g. DBIC:S:L::DBI::Pg.  So,
    # I'll have what she's having..
    {
        my $isa = $class . "::ISA";
        no strict 'refs'; @$isa = (ref $new);
    }

    eval("require $_") || die for @{$new->left_base_classes};
    bless $new, $class;
}

sub _load_tables {
    my ($self, @tables) = @_;

    # Save the new tables to the tables list and compute monikers
    foreach (@tables) {
        $self->_tables->{$_->sql_name}  = $_;
        $self->monikers->{$_->sql_name} = $self->_table2moniker($_);
    }

    # "check for moniker clashes": NEED TO FACTOR OUT THIS ALGORITHM FROM ::Base.  leave it out for now.

    $self->_make_src_class($_) for @tables;
    $self->_setup_src_meta($_) for @tables;

    # Here's the "Rinse-and-Repeat" Catch-22 that causes so much dbics::loader agony:
    # - 'register_class' freezes what we know about the class so far.
    # - relationships cannot be dynamically added until classes are registered.
    # Solution: register all classes while still unrelated, then build relationships, then wipe-and-reregister.

    for my $table (@tables) {
        my $moniker = $self->monikers->{$table->sql_name};
        my $class = $self->classes->{$table->sql_name};
        $self->schema->register_class($moniker=>$class);
    }

    $self->_load_relationships(\@tables);

    # load user-defined customisations as 'mix-ins' if present.
    for my $class (sort values %{$self->classes}) {
        if (eval "require $class") {
            printf STDERR "$class customisations loaded\n" if $self->debug;
            next
        }
        my $err = $@;
        next if $err =~ /Can't locate/; # It's not a sin..
        printf STDERR "WARNING errors loading customisations for $class.. %s\n", $err;
    }

    # rinse and repeat..
    $self->schema->source_registrations({});
    for my $table (@tables) {
        my $moniker = $self->monikers->{$table->sql_name};
        my $class = $self->classes->{$table->sql_name};
        $self->schema->register_class($moniker=>$class);
    }

    # all table meta-data including relationships are now has fully 'registered'.
    return \@tables;
}

# Override existing Loader::Base actions to actually run code rather than generate it..

sub _dbic_stmt {
    my ($self, $class, $method, @args) = @_;
    printf STDERR "DBIC_STMT %s ( %s )\n", "$class->$method(@args);", Dumper(\@args) if $self->debug;
    $class->$method(@args);
}

sub _inject {
    my ($self, $class, @parents) = @_;
    return unless @parents;
    my $isa = "$class\::ISA";
    no strict 'refs';
    unshift @$isa, @parents;
}

sub _base_class_pod {}
sub _make_pod {}
sub _make_pod_heading {}
sub _pod {}
sub _pod_class_list {}
sub _pod_cut {}
sub _use {}

1;

__END__