File Coverage

blib/lib/DBIx/CSVDumper.pm

Criterion	Covered	Total	%
statement	15	41	36.5
branch	0	14	0.0
condition	0	14	0.0
subroutine	5	9	55.5
pod	4	4	100.0
total	24	82	29.2

package DBIx::CSVDumper;
use strict;
use warnings;
use utf8;
use Encode;
use Text::CSV;

our $VERSION = '0.02';

our %DEFAULT_CSV_ARGS = (
    binary          => 1,
    always_quote    => 1,
    eol             => "\r\n",
);

sub new {
    my $class = shift;
    my %args = @_ == 1 ? %{$_[0]} : @_;
    bless {%args}, $class;
}

sub csv_obj {
    my ($self, $obj) = @_;
    $self->{_csv_obj} = $obj if $obj;
    $self->{_csv_obj} ||= Text::CSV->new({
        %DEFAULT_CSV_ARGS,
        %{ $self->{csv_args} || {} },
    });
}

sub encoding {
    my ($self, $enc) = @_;
    $self->{_encoding} = Encode::find_encoding($enc) if $enc;
    $self->{_encoding} ||= Encode::find_encoding($self->{encoding} || 'utf-8');
}

sub dump {
    my ($self, %args) = @_;
    my $sth      = $args{sth};
    my $file     = $args{file};
    my $fh       = $args{fh};
    my $encoding = $args{encoding} || $self->encoding;

    $sth->execute if $DBI::VERSION >= 1.41 && !$sth->{Executed};

    unless ($fh) {
        open $fh, '>', $file or die $!;
    }

    my $csv = $self->csv_obj;
    my $cols = $sth->{NAME};
    $csv->print($fh, $cols);
    while (my @data = $sth->fetchrow_array) {
        @data = map {encode($encoding => $_)} @data;
        $csv->print($fh, [@data]);
    }
}

1;
__END__