File Coverage

blib/lib/Crypt/XkcdPassword.pm

Criterion	Covered	Total	%
statement	40	45	88.8
branch	8	12	66.6
condition	3	3	100.0
subroutine	10	11	90.9
pod	1	1	100.0
total	62	72	86.1

package Crypt::XkcdPassword;

use 5.010001;
use utf8;

BEGIN {
	$Crypt::XkcdPassword::AUTHORITY = "cpan:TOBYINK";
	$Crypt::XkcdPassword::VERSION   = "0.005";
}

use match::simple   qw( M );
use Carp            qw( carp croak );
use Module::Runtime qw( require_module );
use Types::Standard qw( CodeRef Str );

use Moo;
with qw(Role::Commons::Authority);

has rng => (
	is      => "rw",
	isa     => CodeRef,
	default => sub { sub { int(rand($_[0])) } },
);

has words => (
	is      => "rw",
	isa     => Str,
	default => sub { "EN" },
);

*chars = *provider = sub {};

sub make_password
{
	my ($self, $length, $filter) = @_;

	$self = $self->new unless ref $self;

	$length = 4 unless defined $length;
	$length = 4 unless $length > 0;

	my $rng        = $self->rng;
	my $words      = $self->_word_list;
	my $word_count = @$words;

	my @password;
	while (@password < $length)
	{
		local $_ = my $maybe = $words->[ $rng->($word_count) ];
		push @password, $maybe
			if (!defined $filter or $maybe |M| $filter);
	}

	return join q{ }, @password;
}

sub _word_list
{
	my ($self) = @_;
	my $class = sprintf "Crypt::XkcdPassword::Words::%s", $self->words;

	eval { require_module($class) } or do {
		carp "$class could not be loaded, switching to 'EN'";
		croak "No point switching!" if $self->words eq "EN";
		$self->words("EN");
		return $self->_word_list;
	};

	return $class->words;
}

__PACKAGE__
__END__