File Coverage

blib/lib/Crypt/Password/StretchedHash.pm

Criterion	Covered	Total	%
statement	67	67	100.0
branch	18	22	81.8
condition	16	18	88.8
subroutine	11	11	100.0
pod	4	4	100.0
total	116	122	95.0

package Crypt::Password::StretchedHash;
use 5.008005;
use strict;
use warnings;

our $VERSION = "0.05";

use Exporter qw(
    import
);
use Carp qw(
    croak
);
use MIME::Base64 qw(
    encode_base64
    decode_base64
);
use Params::Validate qw(
    SCALAR
);

our @EXPORT_OK = qw(
    crypt
    verify
    crypt_with_hashinfo
    verify_with_hashinfo
);

sub crypt {

    my %params = Params::Validate::validate(@_, {
        password        => { type => SCALAR },
        hash            => 1,
        salt            => { type => SCALAR },
        stretch_count   => { type => SCALAR, regex => qr/\A[0-9]+\z/,},
        format          => { type => SCALAR, optional => 1 },
    });

    my $salt = $params{salt};
    croak "\$params{hash} must be Digest::SHAx Object"
        unless ( $params{hash}->isa("Digest::SHA") ||
                $params{hash}->isa("Digest::SHA3"));

    my $hash = $params{hash};

    croak "\$params{stretch_count} must be more than 1"
        unless ($params{stretch_count} > 0);

    my $pwhash = q{};
    for (1..$params{stretch_count}) {
        $hash->add( $pwhash, $params{password}, $salt );
        $pwhash = $hash->digest;
    }

    if ( exists $params{format} && $params{format} eq q{hex} ){
        $pwhash = unpack("H*", $pwhash);
    }elsif( exists $params{format} && $params{format} eq q{base64} ){
        $pwhash = encode_base64 $pwhash;
        $pwhash =~ s/\n//;
        chomp($pwhash);
    }

    return $pwhash;
}

sub verify {

    my %params = Params::Validate::validate(@_, {
        password        => { type => SCALAR },
        password_hash   => { type => SCALAR },
        hash            => 1,
        salt            => { type => SCALAR },
        stretch_count   => { type => SCALAR, regex => qr/\A[0-9]+\z/,},
        format          => { type => SCALAR, optional => 1 },
    });

    my $pwhash = $params{password_hash};
    delete $params{password_hash};
    my $calculated_pwhash = Crypt::Password::StretchedHash::crypt( %params );
    return ( $calculated_pwhash eq $pwhash );
}

sub crypt_with_hashinfo {

    my %params = Params::Validate::validate(@_, {
        password    => { type => SCALAR },
        hash_info   => 1,
    });

    # validate hashinfo object
    my $hash_info = $params{hash_info};
    croak "\$params{hash_info} must be Crypt::Password::StretchedHash::HashInfo Object"
        unless ( $hash_info->isa("Crypt::Password::StretchedHash::HashInfo") );

    my $salt = $hash_info->salt;

    my $pwhash = Crypt::Password::StretchedHash::crypt(
        password        => $params{password},
        hash            => $hash_info->hash,
        salt            => $salt,
        stretch_count   => $hash_info->stretch_count,
        format          => $hash_info->format,
    );

    if ( $hash_info->format eq q{hex} ){
        $salt = unpack("H*", $salt);
    }elsif( $hash_info->format eq q{base64} ){
        $salt = encode_base64 $salt;
        chomp($salt);
    }

    return  $hash_info->delimiter .
            $hash_info->identifier.
            $hash_info->delimiter.
            $salt.
            $hash_info->delimiter.
            $pwhash;

}

sub verify_with_hashinfo {

    my %params = Params::Validate::validate(@_, {
        password        => { type => SCALAR },
        password_hash   => { type => SCALAR },
        hash_info       => 1,
    });

    # validate hashinfo object
    my $hash_info = $params{hash_info};
    croak "\$params{hash_info} must be Crypt::Password::StretchedHash::HashInfo Object"
        unless ( $hash_info->isa("Crypt::Password::StretchedHash::HashInfo") );

    # split password hash
    my $delimiter = quotemeta($hash_info->delimiter);
    my $identifier = $hash_info->identifier;
    my ( $pwhash, $salt );

    my @split_password_hash = split( /$delimiter/, $params{password_hash} );
    if ($params{password_hash} =~ /\A$delimiter/ &&
        scalar @split_password_hash == 4 &&
        $split_password_hash[0] eq q{} &&
        $identifier eq $split_password_hash[1] ){
        $salt = $split_password_hash[2];
        $pwhash = $split_password_hash[3];
    } else {
        return;
    }

    # obtain law_salt string
    if ( $hash_info->format eq q{hex} ){
        $salt = pack("H*", $salt);
    }elsif( $hash_info->format eq q{base64} ){
        $salt = decode_base64 $salt;
    }

    # generate hashed password
    my $expected_pwhash = Crypt::Password::StretchedHash::crypt(
        password        => $params{password},
        hash            => $hash_info->hash,
        salt            => $salt,
        stretch_count   => $hash_info->stretch_count,
        format          => $hash_info->format,
    );
    return ( $expected_pwhash eq $pwhash );

}

1;
__END__