File Coverage

blib/lib/Couchbase/Couch/Base.pm

Criterion	Covered	Total	%
statement	33	83	39.7
branch	0	20	0.0
condition	0	3	0.0
subroutine	11	19	57.8
pod	5	6	83.3
total	49	131	37.4

# This module forms the CouchDB parts of
# Couchbase::Client's API

package Couchbase::Couch::Base;
use strict;
use warnings;
use Couchbase::Couch::Handle;
use Couchbase::Couch::HandleInfo;
use Couchbase::Couch::Design;
use Couchbase::Client::IDXConst;
use JSON;
use JSON::SL;
use Data::Dumper;
use URI;


sub _CouchCtorInit {
    my ($cls,$av) = @_;
    $av->[CTORIDX_JSON_ENCODE_METHOD] = \&encode_json;
}

# The following methods are defined in Client.xs
# and alias to the memcached set() method, with
# special behavior for converting objects into
# JSON

# couch_store, couch_set
# couch_add
# couch_replace
# couch_cas

my %STRMETH_MAP = (
    GET => COUCH_METHOD_GET,
    POST => COUCH_METHOD_POST,
    PUT => COUCH_METHOD_PUT,
    DELETE => COUCH_METHOD_DELETE
);


# Returns a 'raw' request handle
sub couch_handle_raw {
    my ($self,$meth,$path,$body) = @_;
    my $imeth = $STRMETH_MAP{$meth};
    if (!defined $imeth) {
        die("Unknown method: $meth");
    }
    return $self->_couch_handle_new(\%Couchbase::Couch::Handle::RawIterator::);
}

# gets a couch document. Quite simple..
sub couch_doc_get {
    my $self = shift;
    my $ret = $self->get(@_);
    if ($ret->value) {
        $ret->[RETIDX_VALUE] = decode_json($ret->[RETIDX_VALUE]);
    }
    return $ret;
}

{
    no warnings 'once';
    *couch_doc_store = *Couchbase::Client::couch_set;
}

# Gets a design document
sub couch_design_get {
    my ($self,$path) = @_;
    my $handle = $self->_couch_handle_new(
        \%Couchbase::Couch::Handle::Slurpee::);
    my $design = $handle->slurp_jsonized(COUCH_METHOD_GET, "_design/" . $path, "");
    bless $design, 'Couchbase::Couch::Design';
}

# saves a design document
sub couch_design_put {
    my ($self,$design,$path) = @_;
    if (ref $design) {
        $path = $design->{_id};
        $design = encode_json($design);
    }
    my $handle = $self->_couch_handle_new(\%Couchbase::Couch::Handle::Slurpee::);
    return $handle->slurp_jsonized(COUCH_METHOD_PUT, $path, $design);
}

sub _process_viewpath_common {
    my ($orig,%options) = @_;
    my %qparams;

    if (delete $options{ForUpdate}) {
        $qparams{include_docs} = "true";
    }
    if (%options) {
        # TODO: pop any other known parameters?
        %qparams = (%qparams,%options);
    }

    if (ref $orig eq 'ARRAY') {
        unless ($orig->[0] && $orig->[1]) {
            die("Path cannot be empty");
        }

        # Assume this is an array of [ design, view ]
        $orig = sprintf("_design/%s/_view/%s", @$orig);
    }

    if (!$orig) {
        die("Path cannot be empty");
    }


    if (%qparams) {
        $orig = URI->new($orig);
        $orig->query_form(\%qparams);
    }

    return $orig . "";
}

# slurp an entire resultset of views
sub couch_view_slurp {
    my ($self,$viewpath,%options) = @_;
    my $handle = $self->_couch_handle_new(
        \%Couchbase::Couch::Handle::Slurpee::);
    if (delete $options{ForUpdate}) {
        $viewpath .= "?include_docs=true";
    }
    $viewpath = _process_viewpath_common($viewpath,%options);
    $handle->slurp(COUCH_METHOD_GET, $viewpath, "");

}

sub couch_view_iterator {
    my ($self,$viewpath,%options) = @_;

    $viewpath = _process_viewpath_common($viewpath, %options);

    my $handle = $self->_couch_handle_new(
        \%Couchbase::Couch::Handle::ViewIterator::);

    $handle->_perl_initialize();
    $handle->prepare(COUCH_METHOD_GET, $viewpath, "");
    return $handle;
}

0xf00d

__END__