File Coverage

blib/lib/Cisco/SNMP/System.pm

Criterion	Covered	Total	%
statement	16	70	22.8
branch	0	12	0.0
condition	0	6	0.0
subroutine	6	19	31.5
pod	11	11	100.0
total	33	118	27.9

package Cisco::SNMP::System;

##################################################
# AUTHOR = Michael Vincent
# www.VinsWorld.com
##################################################

use strict;
use warnings;

use Net::SNMP qw(:asn1);
use Cisco::SNMP;

our $VERSION = $Cisco::SNMP::VERSION;

our @ISA = qw(Cisco::SNMP);

##################################################
# Start Public Module
##################################################

sub _sysOID {
    return '1.3.6.1.2.1.1'
}

sub sysOIDs {
    return qw(Descr ObjectID UpTime Contact Name Location Services ORLastChange)
}

sub system_info {
    my $self  = shift;
    my $class = ref($self) || $self;

    my $session = $self->{_SESSION_};

    my $response = Cisco::SNMP::_snmpwalk($session, _sysOID());
    if (defined $response) {

        my $sysinfo;
        my @SYSKEYS = sysOIDs();
        for (0..$#SYSKEYS) {
            $sysinfo->{$SYSKEYS[$_]}  = $response->[$_]
        }
        return bless $sysinfo, $class
    } else {
        $Cisco::SNMP::LASTERROR = "Cannot read system MIB";
        return undef
    }
}

sub sysDescr {
    my $self = shift;
    return $self->{Descr}
}

sub sysObjectID {
    my $self = shift;
    return $self->{ObjectID}
}

sub sysUpTime {
    my $self = shift;
    return $self->{UpTime}
}

sub sysContact {
    my $self = shift;
    return $self->{Contact}
}

sub sysName {
    my $self = shift;
    return $self->{Name}
}

sub sysLocation {
    my $self = shift;
    return $self->{Location}
}

sub sysORLastChange {
    my $self = shift;
    return $self->{ORLastChange}
}

sub sysServices {
    my ($self, $arg) = @_;

    if (defined($arg) && ($arg >= 1)) {
        return $self->{Services}
    } else {
        my %Services = (
            1  => 'Physical',
            2  => 'Datalink',
            4  => 'Network',
            8  => 'Transport',
            16 => 'Session',
            32 => 'Presentation',
            64 => 'Application'
        );
        my @Svcs;
        for (sort {$b <=> $a} (keys(%Services))) {
            push @Svcs, $Services{$_} if ($self->{Services} & int($_))
        }
        return \@Svcs
    }
}

sub sysOSVersion {
    my $self = shift;

    if ($self->{Descr} =~ /Version ([^ ,\n\r]+)/) {
        return $1
    } else {
        return "Cannot determine OS Version"
    }
}

no strict 'refs';
# get_ direct
my @OIDS = sysOIDs();
for my $o (0..$#OIDS) {
    *{"get_sys" . $OIDS[$o]} = sub {
        my $self  = shift;

        my $s = $self->session;
        my $r = $s->get_request(
            varbindlist => [_sysOID() . '.' . ($o+1) . '.0']
        );
        return $r->{_sysOID() . '.' . ($o+1) . '.0'}
    }
}

# set_ direct
for my $o (3..5) {
    *{"set_sys" . $OIDS[$o]} = sub {
        my $self  = shift;
        my ($val) = @_;

        if (!defined $val) { $val = '' }
        my $s = $self->session;
        my $r = $s->set_request(
            _sysOID() . '.' . ($o+1) . '.0', OCTET_STRING, $val
        );
        if (!defined $r) {
            $Cisco::SNMP::LASTERROR = $s->error;
            return
        } else {
            return $r->{_sysOID() . '.' . ($o+1) . '.0'}
        }
    }
}

##################################################
# End Public Module
##################################################

1;

__END__