File Coverage

blib/lib/CMS/Drupal/Modules/MembershipEntity.pm

Criterion	Covered	Total	%
statement	65	72	90.2
branch	12	16	75.0
condition	2	5	40.0
subroutine	9	9	100.0
pod	1	1	100.0
total	89	103	86.4

package CMS::Drupal::Modules::MembershipEntity;
$CMS::Drupal::Modules::MembershipEntity::VERSION = '0.96';
# ABSTRACT: Perl interface to Drupal MembershipEntity entities

use strict;
use warnings;

use Moo;
use Types::Standard qw/ :all /;
use Time::Local;
use Carp qw/ carp croak /;

use CMS::Drupal::Modules::MembershipEntity::Membership;
use CMS::Drupal::Modules::MembershipEntity::Term;

has dbh    => ( is => 'ro', isa => InstanceOf['DBI::db'], required => 1 );
has prefix => ( is => 'ro', isa => Maybe[StrMatch[ qr/ \w+_ /x ]] );

sub fetch_memberships {

  my $self = shift;

  ## We accept a list of mids as an optional parameter
  my @mids = @_;

  my $WHERE = ' ';

  if ( @mids ) {
    if ( scalar @mids < 1 ) {
      carp 'Empty array passed to fetch_memberships() ... returning all Memberships';
    }

    if ( ! grep { /all/ } @mids ) {
       # ^ in that case no WHERE clause

      for ( @mids ) {
        # Let's be real strict about what we try to pass in to the DBMS
        croak 'FATAL: Invalid mid (must be all ASCII digits).'
          unless /^[0-9]+$/;

        $WHERE = 'WHERE ';
        $WHERE .= "mid = '$_' OR " for @mids;
        $WHERE =~ s/ OR $//;
      }
    }
  }

  my $prefix = ( $self->{'prefix'} || '' );

  my %temp;
  my %memberships;

  ## Get the Membership info
  my $sql = qq|
    SELECT mid, member_id, type, uid, status, created, changed
    FROM ${prefix}membership_entity
    $WHERE
  |;

  my $sth = $self->{'dbh'}->prepare( $sql );
  $sth->execute;

  my $results = $sth->fetchall_hashref('mid');
  foreach my $mid (keys( %{ $results } )) {
    $temp{ $mid } = $results->{ $mid };
  }

  ## Get the Membership Term info
  #  Use the $WHERE clause from the optional mids parameter
  my $sql2 = qq|
    SELECT id as tid, mid, status, term, modifiers, start, end
    FROM ${prefix}membership_entity_term
    $WHERE
    ORDER BY start
  |;

  my $sth2 = $self->{'dbh'}->prepare( $sql2 );
  $sth2->execute;

  my %term_count; # used to track array position of Terms

  while( my $row = $sth2->fetchrow_hashref ) {

    ## Shouldn't be, but is, possible to have a Term with no
    ## start or end date
    if ( not defined $row->{'start'} or not defined $row->{'end'} ) {
      carp "MISSING DATE: tid[ $row->{'tid'} ] " .
           "(uid[ $temp{ $row->{'mid'} }->{'uid'} ]) has no start " .
           "or end date defined. Skipping ...";
      next;
    }

    ## Shouldn't be, but is, possible to have a Term with no
    ## corresponding Memberships
    if ( not defined $temp{ $row->{'mid'} } ) {
      carp "TERM WITH NO MEMBERSHIP: tid[ $row->{'tid'} ] " .
           "has no corresponding Membership. Skipping ...";
      next;
    }

    ## convert the start and end to unixtime
    for (qw/ start end /) {
      my @datetime = reverse ( split /[-| |:]/, $row->{ $_ } );
      $datetime[4]--;
      $row->{ $_ } = timelocal( @datetime );
    }

    ## Track which of the Membership's Terms this is
    $term_count{ $row->{'mid'} }++;
    $row->{'array_position'} = $term_count{ $row->{'mid'} };

    ## Instantiate a MembershipEntity::Term object for each
    ## Term now that we have the data
    my $term = CMS::Drupal::Modules::MembershipEntity::Term->new( $row );
    $temp{ $row->{'mid'} }->{'terms'}->{ $row->{'tid'} } = $term;
  }

  ## Instantiate a MembershipEntity::Membership object for each
  ## Membership now that we have the data
  foreach my $mid(keys( %temp )) {

    ## Shouldn't be, but is, possible to have a Membership with no Term
    if (not defined $temp{ $mid }->{'terms'}) {
      carp "MISSING TERM: mid[ $mid ] (uid[ $temp{ $mid }->{'uid'} ]) " .
           "has no Membership Terms. Skipping ...";
      next;
    }

    $memberships{ $mid } =
    CMS::Drupal::Modules::MembershipEntity::Membership->new( $temp{ $mid } );
  }

  $self->{'_memberships'} = \%memberships;

  return (scalar keys %memberships == 1) ?
       @memberships{ keys %memberships } :
                            \%memberships;
}

1; ## return true to end package CMS::Drupal::Modules::MembershipEntity

__END__