File Coverage

blib/lib/CGI/Application/Plugin/Flash.pm

Criterion	Covered	Total	%
statement	34	38	89.4
branch	9	14	64.2
condition	2	2	100.0
subroutine	7	7	100.0
pod	2	2	100.0
total	54	63	85.7

package CGI::Application::Plugin::Flash;
use Carp;
use CGI::Session::Flash;
use strict;

our $VERSION = "0.02";


# Export our flash functions and set up the necessary CGI::Application
# hooks.
sub import
{
    my $package = shift;
    my $caller  = caller;

    # Export the flash methods
    {
        no strict 'refs';
        *{"$caller\::flash"}        = \&flash;
        *{"$caller\::flash_config"} = \&flash_config;
    }

    return 1;
}

# Retrieve the flash object.  This method also provides a convenient simple
# syntax for setting and getting data from the flash.
sub flash
{
    my $self = shift;
    my $flash;

    # Create the flash object singleton.
    if (!defined $self->{'__CAP_FLASH_OBJECT'})
    {
        croak "Flash requires session support." unless ($self->can("session"));

        $self->{'__CAP_FLASH_OBJECT'} =
            CGI::Session::Flash->new($self->session, $self->flash_config);
    }

    $flash = $self->{'__CAP_FLASH_OBJECT'};

    # Set or get the values for a specific key.
    if (@_)
    {
        my $key = shift;

        if (@_)
        {
            $flash->set($key => @_);
        }

        return $flash->get($key);
    }
    # Return the flash object.
    else
    {
        return $flash;
    }
}

sub flash_config
{
    my $self = shift;

    # Set the values of the configuration.
    if (@_)
    {
        croak "Invalid flash configuration.  Specify a list of name and values."
            if (@_ % 2 == 1);

        $self->{'__CAP_FLASH_CONFIG'} = { @_ };
    }

    # Return the config.
    my $config = $self->{'__CAP_FLASH_CONFIG'} || { };
    return wantarray ? %$config : $config;
}

1;
__END__