File Coverage

blib/lib/Business/OnlinePayment/iTransact.pm

Criterion	Covered	Total	%
statement	23	135	17.0
branch	0	32	0.0
condition	0	2	0.0
subroutine	8	12	66.6
pod	2	4	50.0
total	33	185	17.8

##############################################################################
# Business::OnlinePayment::iTransact
#
# Credit card transactions via iTransact's XML API Connection
#
# Refer to iTransact's documentation for more info
# https://itransact.com/support/toolkit/xml-connection/api/
#
# AUTHOR
#
# Bill Gerrard
#
# BUSINESS::ONLINEPAYMENT IMPLEMENTATION
#
# Bill Gerrard
#
# VERSION HISTORY
#
# + v1.01       03/24/2018 Added option to pass line item detail
# + v1.00	07/17/2017 Business::OnlinePayment implementation
#
# COPYRIGHT AND LICENSE
#
# Copyright (C) 2017-2018 Bill Gerrard
#
# This program is free software; you can redistribute it and/or modify
# it under the same terms as Perl itself, either Perl version 5.20.2 or,
# at your option, any later version of Perl 5 you may have available.
#
# Disclaimer of warranty: This program is provided by the copyright holder
# and contributors "As is" and without any express or implied warranties.
# The implied warranties of merchantability, fitness for a particular purpose,
# or non-infringement are disclaimed to the extent permitted by your local
# law. Unless required by law, no copyright holder or contributor will be
# liable for any direct, indirect, incidental, or consequential damages
# arising in any way out of the use of the package, even if advised of the
# possibility of such damage.
#
################################################################################

package Business::OnlinePayment::iTransact;

use 5.008004;
use strict;
use Carp;
use Business::OnlinePayment 3;
use Business::OnlinePayment::HTTPS;

# iTransact specific prerequisites:
use XML::Writer;
use XML::Hash::XS qw();
use Digest::HMAC_SHA1;

our @ISA = qw(Business::OnlinePayment::HTTPS);
our $VERSION = '1.01';

sub set_defaults {
    my $self = shift;

    $self->server('secure.itransact.com');
    $self->port('443');
    $self->path('/cgi-bin/rc/xmltrans2.cgi');

    $self->build_subs(qw(
        avs_category timestamp total card_type
        error_category warning_message auth_amount
    ));
}

sub map_fields {
    my ( $self ) = @_;
    my %content = $self->content();

    my $action  = lc( $content{'action'} );
    my %map = (
        'normal authorization' => 'AuthTransaction',
        #'authorization only'   => 'AuthTransaction-PreAuth',
        #'avs only'             => 'AuthTransaction-AVSOnly',
        ## 'credit'               => 'TranCredTransaction',
        ## 'post authorization'   => 'PostAuthTransaction',
        ## 'void'                 => 'VoidTransaction',
    );
    $content{'action_type'} = $map{$action}
      or croak 'Invalid action: '. $action;

    $self->transaction_type($content{'type'});

    $self->content( %content );
}

sub submit {
    my($self) = @_;

    $self->map_fields();

    my %c = $self->content();

    # check required fields: if no items array, amount/description required
    my @required_fields = qw(type action
        first_name last_name card_number expiration);
    unless ( defined $c{'items'} ) {
      push @required_fields, 'description';
      push @required_fields, 'amount';
    }
    $self->required_fields( @required_fields );

    if ( lc( $c{'type'} ) =~ /^e?check$/i ) {
      $self->is_success(0);
      $self->error_message('Business::OnlinePayment::iTransact does not currently support checks');
      return;
    }

    my $action = $c{action_type};

    ### start XML generation

    my $writer = XML::Writer->new( OUTPUT => 'self' );

    $writer->startTag($action);

    $writer->startTag('TransactionControl');
      $writer->dataElement('SendCustomerEmail', $self->email_customer);
      $writer->dataElement('SendMerchantEmail', $self->email_merchant);
      $writer->dataElement('TestMode', $self->{test_mode} ? 'TRUE' : 'FALSE');
    $writer->endTag('TransactionControl');

    $writer->startTag('CustomerData');
      $writer->dataElement('CustId', $c{customer_id});
      $writer->dataElement('Email', $c{email});
      $writer->startTag('BillingAddress');
        $writer->dataElement('Address1', $c{address});
        $writer->dataElement('FirstName', $c{first_name});
        $writer->dataElement('LastName', $c{last_name});
        $writer->dataElement('City', $c{city});
        $writer->dataElement('State', $c{state});
        $writer->dataElement('Zip', $c{zip});
        $writer->dataElement('Country', $c{country});
        $writer->dataElement('Phone', $c{phone});
      $writer->endTag('BillingAddress');
    $writer->endTag('CustomerData');

    if (lc $c{type} eq 'cc') {

      # expiration date
      $c{'expiration'} =~ /^(\d+)\D+\d*(\d{2})$/
        or croak "unparsable expiration ". $c{expiration};
      my( $month, $year ) = ( $1, $2 );
      $month = '0'. $month if $month =~ /^\d$/;
      $year = '20' . $year if length($year) == 2;

      $writer->startTag('AccountInfo');
        $writer->startTag('CardAccount');
          $writer->dataElement('AccountNumber', $c{card_number});
          $writer->dataElement('ExpirationMonth', $month);
          $writer->dataElement('ExpirationYear', $year);
          $writer->dataElement('CVVNumber', $c{cvv2});
        $writer->endTag('CardAccount');
      $writer->endTag('AccountInfo');

    }

    if ( defined($c{'items'}) ) {
      $writer->startTag('OrderItems');
      foreach my $itm ( @{$c{'items'}} ) {
        $writer->startTag('Item');
          foreach my $key ( qw( description qty cost ) ) {
            $writer->dataElement(ucfirst($key), $itm->{$key});
          }
        $writer->endTag('Item');
      }
      $writer->endTag('OrderItems');
    } else {
      $writer->dataElement('Description', $c{description});
      $writer->dataElement('Total', $c{amount});
    }

    $writer->endTag($action); # root

    my $xml_payload = $writer->to_string;

    ### payload built, now generate payload signature

    my $hmac = Digest::HMAC_SHA1->new($self->password);
    $hmac->add($xml_payload);
    my $payload_signature = $hmac->b64digest . '='; # add closing '=' to signature
    my $username = $self->login;

    my $xml_request = qq{


          $username
          $payload_signature

        $xml_payload

    };

    ### end XML generation

    my ( $page, $status_code, %headers ) =
        $self->https_post( { 'Content-Type' => 'text/xml; charset=utf-8' } , $xml_request);

    my $response = {};
    if ( $status_code =~ /^200/ ) {
        if ( ! eval {
            my $conv = XML::Hash::XS->new(utf8 => 0, encoding => 'utf-8');
            my $hash = $conv->xml2hash($page);
            $response = $hash->{TransactionResponse}->{TransactionResult};
        } ) {
            die "XML PARSING FAILURE: $@";
        }
    }
    else {
        $status_code =~ s/[\r\n\s]+$//; # remove newline so you can see the error in a linux console
        die "CONNECTION FAILURE: $status_code";
    }

    $self->server_response( $page );
    $self->authorization( $response->{AuthCode} );
    $self->order_number(  $response->{XID} );
    $self->avs_code( $response->{AVSResponse} );
    $self->cvv2_response( $response->{CVV2Response} );
    # iTransact specific return fields
    $self->avs_category( $response->{AVSCategory} );
    $self->timestamp( $response->{TimeStamp} );
    $self->total( $response->{Total} );
    $self->auth_amount( $response->{AuthAmount} );
    $self->card_type( $response->{CardName} );

    if ($response->{Status} eq 'ok') { #success
        $self->is_success(1);
    } else {
      $self->is_success(0);
      $self->error_message( $response->{ErrorMessage} );
      $self->error_category( $response->{ErrorCategory} );
    }

}

sub test_transaction {
    my $self = shift;
    my $testMode = shift;
    if (! defined $testMode) { $testMode = $self->{test_mode} || 0; }

    $testMode = 1 if uc $testMode eq 'TRUE';
    $testMode = 0 if uc $testMode eq 'FALSE';

    if ($testMode) {
        $self->{test_mode} = 1;
    } else {
        $self->{test_mode} = 0;
    }

    return $self->{test_mode};
}

1;

__END__