File Coverage

blib/lib/Business/ID/NPWP.pm

Criterion	Covered	Total	%
statement	23	26	88.4
branch	8	14	57.1
condition			n/a
subroutine	5	5	100.0
pod	1	1	100.0
total	37	46	80.4

package Business::ID::NPWP;

our $DATE = '2015-09-03'; # DATE
our $VERSION = '0.07'; # VERSION

use 5.010001;
use warnings;
use strict;

require Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(parse_npwp);

our %SPEC;

sub _z { $_[0] > 9 ? $_[0]-9 : $_[0] }

$SPEC{parse_npwp} = {
    v => 1.1,
    summary => 'Parse Indonesian taxpayer registration number (NPWP)',
    args => {
        npwp => {
            summary => 'Input NPWP to be parsed',
            schema  => 'str',
            pos => 0,
            req => 1,
        },
    },
};
sub parse_npwp {
    my %args = @_;

    my $npwp = $args{npwp} or return [400, "Please specify npwp"];
    my $res = {};

    $npwp =~ s/^\s+//;
    # assume A = 0 if not specified
    if ($npwp =~ /^\d\./) { $npwp = "0$npwp" }

    $npwp =~ s/\D+//g;
    # assume BBB = 000 if not specified
    if (length($npwp) == 12) { $npwp .= "000" }
    return [400, "Not 15 digit"] unless length($npwp) == 15;

    $npwp =~ /^(.)(.)(.)(.)(.)(.)(.)(.)(.)/;
    if ((_z(1*$1) + _z(2*$2) + _z(1*$3) +
	 _z(2*$4) + _z(1*$5) + _z(2*$6) +
         _z(1*$7) + _z(2*$8) + _z(1*$9)) % 10) {
        return [400, "Wrong check digit"];
    }

    (
        $res->{taxpayer_code}, $res->{serial}, $res->{check_digit},
        $res->{tax_office_code}, $res->{branch_code},
    ) = $npwp =~ /(..)(.{6})(.)(...)(...)/;

    return [400, "Serial starts from 1, not 0"] if $res->{serial} < 1;

    $res->{normalized} = join(
        "",
        $res->{taxpayer_code}, ".",
        substr($res->{serial}, 0, 3), ".", substr($res->{serial}, 3), ".",
        $res->{check_digit}, "-",
        $res->{tax_office_code}, ".", $res->{branch_code},
    );

    [200, "OK", $res];
}

1;
# ABSTRACT: Parse Indonesian taxpayer registration number (NPWP)

__END__