File Coverage

blib/lib/Business/Giropay.pm

Criterion	Covered	Total	%
statement	21	35	60.0
branch			n/a
condition			n/a
subroutine	7	12	58.3
pod	5	5	100.0
total	33	52	63.4

package Business::Giropay;

=head1 NAME

Business::Giropay - Giropay payments API

=head1 VERSION

Version 0.102

=cut

our $VERSION = '0.102';

use Business::Giropay::Request::Bankstatus;
use Business::Giropay::Request::Issuer;
use Business::Giropay::Request::Status;
use Business::Giropay::Request::Transaction;
use Business::Giropay::Notification;

use Moo;
with 'Business::Giropay::Role::Core', 'Business::Giropay::Role::Network',
  'Business::Giropay::Role::Urls';
use namespace::clean;

sub bankstatus {
    my ( $self, @args ) = @_;
    my $request = Business::Giropay::Request::Bankstatus->new(
        network    => $self->network,
        merchantId => $self->merchantId,
        projectId  => $self->projectId,
        sandbox    => $self->sandbox,
        secret     => $self->secret,
        @args,
    );
    return $request->submit;
}

sub issuer {
    my $self    = shift;
    my $request = Business::Giropay::Request::Issuer->new(
        network    => $self->network,
        merchantId => $self->merchantId,
        projectId  => $self->projectId,
        sandbox    => $self->sandbox,
        secret     => $self->secret,
    );
    return $request->submit;
}

sub status {
    my ( $self, @args ) = @_;
    my $request = Business::Giropay::Request::Status->new(
        network    => $self->network,
        merchantId => $self->merchantId,
        projectId  => $self->projectId,
        secret     => $self->secret,
        @args,
    );
    return $request->submit;
}

sub transaction {
    my ( $self, @args ) = @_;
    my $request = Business::Giropay::Request::Transaction->new(
        network     => $self->network,
        merchantId  => $self->merchantId,
        projectId   => $self->projectId,
        sandbox     => $self->sandbox,
        secret      => $self->secret,
        urlRedirect => $self->urlRedirect,
        urlNotify   => $self->urlNotify,
        @args,
    );
    return $request->submit;
}

sub notification {
    my ( $self, @args ) = @_;
    return Business::Giropay::Notification->new(
        merchantId => $self->merchantId,
        projectId  => $self->projectId,
        secret     => $self->secret,
        @args,
    );
}

=head1 DESCRIPTION

B implement's Giropay's GiroCheckout API to make direct
calls to Giropay's payments server.

Giropay facilitates payments via various provider networks in addition to
their own. This module currently supports the following networks:

=over

=item eps - EPS (Austria)

=item giropay - Giropay's own network (Germany)

=item ideal - iDEAL (The Netherlands)

=back

Contributions to allow this module to support other networks available via
Giropay are most welcome.

=head1 SYNOPSIS

    use Business::Giropay;

    my $giropay = Business::Giropay->new(
        network    => 'giropay',
        merchantId => '123456789',
        projectId  => '1234567',
        sandbox    => 1,
        secret     => 'project_secret',
    );

    my $response = $giropay->transaction(
        merchantTxId => 'tx-10928374',
        amount       => 2938,               # 29.38 in cents
        currency     => 'EUR',
        purpose      => 'Test Transaction',
        bic          => 'TESTDETT421',
        urlRedirect  => 'https://www.example.com/return_page',
        urlNotify    => 'https://www.example.com/api/giropay/notify',
    );

    if ( $response->success ) {
        # all is good so redirect customer to GiroCheckout
    }
    else {
        # transaction request failed
    }

C and C can also be passed to C:

    use Business::Giropay;

    my $giropay = Business::Giropay->new(
        network     => 'giropay',
        merchantId  => '123456789',
        projectId   => '1234567',
        urlRedirect => 'https://www.example.com/return_page',
        urlNotify   => 'https://www.example.com/api/giropay/notify',
        sandbox     => 1,
        secret      => 'project_secret',
    );

    my $response = $giropay->transaction(
        merchantTxId => 'tx-10928374',
        amount       => 2938,               # 29.38 in cents
        currency     => 'EUR',
        purpose      => 'Test Transaction',
        bic          => 'TESTDETT421',
    );

    if ( $response->success ) {
        # all is good so redirect customer to GiroCheckout
    }
    else {
        # transaction request failed
    }


Elsewhere in your C route:

    my $notification = $giropay->notification( %request_params );

    if ( $notification->success ) {
        # save stuff in DB - customer probably still on bank site
    }
    else {
        # bad stuff happened - make a note of it
    }

And in the C route:

    my $notification = $giropay->notification( %request_params );

    if ( $notification->success ) {
        # we should already have earlier notification but check anyway
        # in case customer came back before we received it then thank
        # customer for purchase
    }
    else {
        # bad stuff - check out the details and tell the customer
    }


=head1 ATTRIBUTES

See L for full details of the
following attributes that can be passed to C.

=over

=item * network

=item * merchantId

=item * projectId

=item * sandbox

=item * secret

=back

See L for full details of the
following attributes that can be passed to C.

=over

=item * urlRedirect

=item * urlNotify

=back

=head1 METHODS

B it is not necessary to pass in any attributes that were already
passed to C since they are passed through automatically.

=head2 bankstatus %attributes

This API call checks if a bank supports the giropay/eps payment method.

Returns a L object.

See L for full details of
the following attribute that can be passed to this method:

=over

=item * bic

=back

=head2 issuer

Returns a L object which includes a
list which contains all supported giropay/eps/ideal issuer banks.

=head2 transaction %attributes

This API call creates the start of a transaction and returns a
L object. If the response indicates
success then customer can be redirected to
L to complete payment.

Returns a L object.

See L for full details of
the following attributes that can be passed to this method:

=over

=item * merchantTxId

=item * amount

=item * currency

=item * purpose

=item * bic

=item * urlRedirect

=item * urlNotify

=back

=head2 notification %query_params

Accepts query parameters and returns a L
object.

=head2 status %attributes

Returns a L object with details of
the requested transaction.

See L for full details of
the following attribute that can be passed to this method:

=over

=item * reference

=back

=head1 SEE ALSO

L which has links for
the various payment network types (giropay, eps, etc). For L see
L.

=head1 TODO

Add more of Giropay's payment networks.

=head1 ACKNOWLEDGEMENTS

Many thanks to L for sponsoring
development of this module.

=head1 LICENSE AND COPYRIGHT

Copyright 2016 Peter Mottram (SysPete)

This program is free software; you can redistribute it and/or modify it
under the terms of Perl itself.

=cut

1;