File Coverage

blib/lib/Build/Hopen/Base.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	1	2	50.0
condition			n/a
subroutine	11	11	100.0
pod			n/a
total	47	48	97.9

# Build::Hopen::Base: common definitions for hopen.
# Thanks to David Farrell,
# https://www.perl.com/article/how-to-build-a-base-module/
# Copyright (c) 2018 Christopher White.  All rights reserved.
# LGPL 2.1+ - see the accompanying LICENSE file

package Build::Hopen::Base;
use parent 'Exporter';
use Import::Into;

our $VERSION = '0.000008'; # TRIAL

# Pragmas
use 5.014;
use feature ":5.14";
use strict;
use warnings;
require experimental;

# Packages
use Data::Dumper;
use Carp;

# Definitions from this file
use constant {
    true => !!1,
    false => !!0,
};

our @EXPORT = qw(true false);
#our @EXPORT_OK = qw();
#our %EXPORT_TAGS = (
#    default => [@EXPORT],
#    all => [@EXPORT, @EXPORT_OK]
#);

#DEBUG
BEGIN {
    $SIG{'__DIE__'} = sub { Carp::confess(@_) } unless $SIG{'__DIE__'};
    #$Exporter::Verbose=1;
}

sub import {
    my $target = caller;

    # Copy symbols listed in @EXPORT first, in case @_ gets trashed later.
    Build::Hopen::Base->export_to_level(1, @_);

    # Re-export pragmas
    feature->import::into($target, qw(:5.14));
    "$_"->import::into($target) foreach qw(strict warnings);

    # Re-export packages
    Data::Dumper->import::into($target);
    Carp->import::into($target, qw(carp croak confess));

    # Permit smartmatch.
    # http://blogs.perl.org/users/mike_b/2013/06/a-little-nicer-way-to-use-smartmatch-on-perl-518.html
    # (Also, https://www.perlmonks.org/?node_id=1163370 is another approach.)
    experimental->import::into($target, 'smartmatch');

} #import()

1;
__END__