File Coverage

blib/lib/Bot/Cobalt/IRC/Message.pm

Criterion	Covered	Total	%
statement	11	11	100.0
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	15	15	100.0

package Bot::Cobalt::IRC::Message;
$Bot::Cobalt::IRC::Message::VERSION = '0.021001';
## Message class. Inherits from Event

use v5.10;
use strictures 2;

use Bot::Cobalt::Common;

use Moo;
extends 'Bot::Cobalt::IRC::Event';

has message => (
  required  => 1,
  is        => 'rw',
  isa       => Str,
  trigger   => sub {
    my ($self, $value) = @_;

    $self->_set_stripped(
      strip_color( strip_formatting($value) )
    ) if $self->has_stripped;

    if ($self->has_message_array) {
      $self->message_array([ split ' ', $self->stripped ]);
    }
  },
);

has targets => (
  required  => 1,
  is        => 'rw',
  isa       => ArrayObj,
  coerce    => 1,
  trigger   => sub {
    my ($self, $value) = @_;
    $self->_set_target($value->[0]) if $self->has_target;
  }
);

has target  => (
  lazy      => 1,
  is        => 'rwp',
  isa       => Str,
  predicate => 'has_target',
  default   => sub { $_[0]->targets->[0] },
);

## May or may not have a channel.
has channel => (
  lazy      => 1,
  is        => 'rw',
  isa       => Str,
  default   => sub {
    $_[0]->target =~ /^[#&+!]/ ? $_[0]->target : ''
  },
);

## Message content.
has stripped => (
  lazy      => 1,
  is        => 'rwp',
  isa       => Str,
  predicate => 'has_stripped',
  default   => sub {
    strip_color( strip_formatting($_[0]->message) )
  },
);

has message_array => (
  lazy      => 1,
  is        => 'rw',
  isa       => ArrayObj,
  coerce    => 1,
  predicate => 'has_message_array',
  default   => sub { [ split ' ', $_[0]->stripped ] },
  trigger   => sub {
    my ($self) = @_;
    if ($self->has_message_array_sp) {
      $self->_set_message_array_sp([ split / /, $self->stripped ]);
    }
  },
);

has message_array_sp => (
  lazy      => 1,
  is        => 'rwp',
  isa       => ArrayObj,
  coerce    => 1,
  predicate => 'has_message_array_sp',
  default   => sub { [ split / /, $_[0]->stripped ] },
);


1;
__END__