File Coverage

blib/lib/Blockchain/Ethereum/ABI/Type/Tuple.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	9	10	90.0
condition	1	2	50.0
subroutine	10	10	100.0
pod	2	2	100.0
total	70	72	97.2

package Blockchain::Ethereum::ABI::Type::Tuple;

use v5.26;
use strict;
use warnings;

use Carp;
use parent qw(Blockchain::Ethereum::ABI::Type);

sub _configure {
    my $self = shift;
    return unless $self->_data;

    my @splited_signatures = $self->_split_tuple_signature->@*;

    for (my $sig_index = 0; $sig_index < @splited_signatures; $sig_index++) {
        push $self->_instances->@*,
            Blockchain::Ethereum::ABI::Type::new_type(
            signature => $splited_signatures[$sig_index],
            data      => $self->_data->[$sig_index]);
    }

}

sub _split_tuple_signature {
    my $self             = shift;
    my $tuple_signatures = substr($self->_signature, 1, length($self->_signature) - 2);
    $tuple_signatures =~ s/((\((?>[^)(]*(?2)?)*\))|[^,()]*)(*SKIP),/$1\n/g;
    my @types = split('\n', $tuple_signatures);
    return \@types;
}

sub encode {
    my $self = shift;
    return $self->_encoded if $self->_encoded;

    my $offset = $self->_get_initial_offset;

    for my $instance ($self->_instances->@*) {
        $instance->encode;
        if ($instance->is_dynamic) {
            $self->_push_static($self->_encode_offset($offset));
            $self->_push_dynamic($instance->_encoded);
            $offset += scalar $instance->_encoded->@*;
            next;
        }

        $self->_push_static($instance->_encoded);
    }

    return $self->_encoded;
}

sub decode {
    my $self = shift;

    unless (scalar $self->_instances->@* > 0) {
        push $self->_instances->@*, Blockchain::Ethereum::ABI::Type::new_type(signature => $_) for $self->_split_tuple_signature->@*;
    }

    return $self->_read_stack_set_data;
}

sub _static_size {
    my $self = shift;
    return 1 if $self->is_dynamic;
    my $size          = 1;
    my $instance_size = 0;
    for my $signature ($self->_split_tuple_signature->@*) {
        my $instance = Blockchain::Ethereum::ABI::Type::new_type(signature => $signature);
        $instance_size += $instance->_static_size // 0;
    }

    return $size * $instance_size;
}

1;

__END__