File Coverage

lib/Beekeeper/Config.pm

Criterion	Covered	Total	%
statement	20	69	28.9
branch	4	44	9.0
condition	0	18	0.0
subroutine	5	9	55.5
pod	3	5	60.0
total	32	145	22.0

package Beekeeper::Config;

use strict;
use warnings;

our $VERSION = '0.09';

use JSON::XS;
use Carp;

my %Cache;
my $Config_dir;


sub set_config_dir {
    my ($class, $dir) = @_;

    croak "Couldn't read config files from $dir: directory does not exist\n" unless ($dir && -d $dir);

    $Config_dir = $dir;
}

sub get_bus_config {
    my ($class, %args) = @_;

    my $bus_id = $args{'bus_id'};

    croak "bus_id was not specified" unless ($bus_id);

    my $config = $class->read_config_file( 'bus.config.json' );

    croak "Couldn't read config file bus.config.json: file not found\n" unless defined ($config);

    my %bus_cfg  = map { $_->{'bus_id'}  => $_ } @$config;

    return ($bus_id eq '*') ? \%bus_cfg : $bus_cfg{$bus_id};
}

sub get_pool_config {
    my ($class, %args) = @_;

    my $pool_id = $args{'pool_id'};

    croak "pool_id was not specified" unless ($pool_id);

    my $config = $class->read_config_file( 'pool.config.json' );

    croak "Couldn't read config file pool.config.json: file not found\n" unless defined ($config);

    my %pool_cfg = map { $_->{'pool_id'} => $_ } @$config;

    return ($pool_id eq '*') ? \%pool_cfg : $pool_cfg{$pool_id};
}

sub get_bus_group_config {
    my ($class, %args) = @_;

    my $bus_role = $args{'bus_role'};
    my $bus_id   = $args{'bus_id'};
    my @group_config;

    croak "No bus_role or bus_id was specified" unless ($bus_id || $bus_role);

    my $config = $class->read_config_file( 'bus.config.json' );

    if ($bus_role) {

        @group_config = grep { defined $_->{'bus_role'} && $_->{'bus_role'} eq $bus_role } @$config;
    }
    elsif ($bus_id) {

        my ($bus_config) = grep { $_->{'bus_id'} eq $bus_id } @$config;
        return [] unless $bus_config;

        $bus_role = $bus_config->{'bus_role'};
        return [ $bus_config ] unless $bus_role;

        @group_config = grep {
            (defined $_->{'bus_role'} && $_->{'bus_role'} eq $bus_role) || $_->{'bus_id'} eq $bus_id
        } @$config;
    }

    return \@group_config;
}

sub read_config_file {
    my ($class, $file) = @_;

    croak "Couldn't read config file: filename was not specified\n" unless ($file);

    my $cdir;
    $cdir = $Config_dir;
    $cdir = $ENV{'BEEKEEPER_CONFIG_DIR'} unless ($cdir && -d $cdir);
    $cdir = '~/.config/beekeeper'        unless ($cdir && -d $cdir);
    $cdir = '/etc/beekeeper'             unless ($cdir && -d $cdir);

    $file = "$cdir/$file";

    return $Cache{$file} if exists $Cache{$file};

    return undef unless (-e $file);

    local($/);
    open(my $fh, '<', $file) or croak "Couldn't read config file $file: $!";
    my $data = <$fh>;
    close($fh);

    # Allow comments and end-comma
    my $json = JSON::XS->new->utf8->relaxed;

    my $config = eval { $json->decode($data) };

    if ($@) {
        croak "Couldn't parse config file $file: Invalid JSON syntax";
    }

    $Cache{$file} = $config;

    return $config;
}

1;

__END__