File Coverage

blib/lib/Bb/Collaborate/Ultra/Session.pm

Criterion	Covered	Total	%
statement	25	39	64.1
branch	1	2	50.0
condition	0	10	0.0
subroutine	7	9	77.7
pod	2	2	100.0
total	35	62	56.4

package Bb::Collaborate::Ultra::Session;
use warnings; use strict;
use Mouse;
extends 'Bb::Collaborate::Ultra::DAO';

use Bb::Collaborate::Ultra::Session::Occurrence;
use Bb::Collaborate::Ultra::Session::RecurrenceRule;
use Mouse::Util::TypeConstraints;

subtype 'ArrayOfOccurrences',
    as 'ArrayRef[Bb::Collaborate::Ultra::Session::Occurrence]';

coerce 'ArrayOfOccurrences',
    from 'ArrayRef[HashRef]',
    via { [ map {Bb::Collaborate::Ultra::Session::Occurrence->new($_)} (@$_) ] };

has 'occurrences' => (isa => 'ArrayOfOccurrences', is => 'rw', coerce => 1);
has 'recurrenceRule' => (isa => 'Bb::Collaborate::Ultra::Session::RecurrenceRule', is => 'rw', coerce => 1);

=head1 NAME

Bb::Collaborate::Ultra::Session

=head1 DESCRIPTION

This class is used to manage Sessions (Virtual Classrooms).

    use Bb::Collaborate::Ultra::Session;
    my $start = time() + 60;
    my $end = $start + 900;

    my $session;
    my $session = Bb::Collaborate::Ultra::Session->post($connection, {
	    name => 'Test Session',
	    startTime => $start,
	    endTime   => $end,
	    },
	);

=head2 Enrolling User in Sessions

AFAIK, there are two classes and two different modes for enrolling user to sessions:

=over 4

=item (*)  Ad-hoc users via L

    my $user = Bb::Collaborate::Ultra::User->new({
	extId => 'testLaunchUser',
	displayName => 'David Warring',
	email => '[e-mail]',
	firstName => 'David',
	lastName => 'Warring',
    });

    my $launch_context = Bb::Collaborate::Ultra::LaunchContext->new({ launchingRole => 'moderator',
	 editingPermission => 'writer',
	 user => $user,
	 });

    my $join_url = $launch_context->join_session($session);

=item (*) Permanently managed users via L

Each user is created once.

    my $ultra_user = Bb::Collaborate::Ultra::User->create($connection, {
	extId => 'testLaunchUser',
	displayName => 'David Warring',
	email => '[e-mail]',
	firstName => 'David',
	lastName => 'Warring',
    });
    my $ultra_user_id = $ultra_user->id;
    # somehow save the user id permanently...

The saved user-id may then be used to multiple times to join sessions:

     my $enrollment =  Bb::Collaborate::Ultra::Session::Enrollment->new({ launchingRole => 'moderator',
	 editingPermission => 'writer',
	 userId => $user2->id,
	 });
      my $join_url = $enrolment->enrol($session)->permanentUrl;

=back

=head1 METHODS

This class supports the `get`, `post`, `patch` and `del` methods as described in L

=cut

sub _thaw {
    my $self = shift;
    my $data = shift;
    my $thawed = $self->SUPER::_thaw($data, @_);
    my $occurrences = $data->{occurrences};
    $thawed->{occurrences} = [ map { Bb::Collaborate::Ultra::Session::Occurrence->_thaw($_) } (@$occurrences) ]
	if $occurrences;
    $thawed;
}

__PACKAGE__->resource('sessions');
__PACKAGE__->load_schema();
__PACKAGE__->query_params(
    name => 'Str',
    userId => 'Str',
    contextId => 'Str',
    startTime => 'Date',
    endTime => 'Date',
    sessionCategory => 'Str',
    );

=head2 get_enrollments

Return a list of users, of type L.

    my @enrollments = $session->get_enrollments;
    for my $enrolment (@enrollments) {
        say "user @{[$enrolment->userId]} is enrolled as a @{[$enrollment->launchingRole]}";
    }

=cut

sub get_enrollments {
    my $self = shift;
    my $query = shift || {};
    my %opt = @_;
    my $connection = $opt{connection} || $self->connection;
    my $path = $self->path.'/enrollments';
    require Bb::Collaborate::Ultra::Session::Enrollment;
    Bb::Collaborate::Ultra::Session::Enrollment->get($connection, $query, path => $path, parent => $self);
}

=head2 get_logs

Returns logging (session-instance) information for completed sessions

=cut

sub get_logs {
    my $self = shift;
    my $query = shift || {};
    my %opt = @_;
    my $connection = $opt{connection} || $self->connection;
    my $path = $self->path.'/instances';
    require Bb::Collaborate::Ultra::Session::Log;
    Bb::Collaborate::Ultra::Session::Log->get($connection, $query, path => $path, parent => $self);
}

1;
# downloaded from https://xx-csa.bbcollab.com/documentation
__DATA__