File Coverage

blib/lib/Bash/History/Read.pm

Criterion	Covered	Total	%
statement	39	44	88.6
branch	7	12	58.3
condition	1	6	16.6
subroutine	8	9	88.8
pod	2	2	100.0
total	57	73	78.0

package Bash::History::Read;

our $DATE = '2015-11-07'; # DATE
our $VERSION = '0.04'; # VERSION

use 5.014;
use strict;
use warnings;

use Exporter 'import';
our @EXPORT = qw(each_hist);
our @EXPORT_OK = qw(parse_bash_history_file);

sub _doit {
    my ($which, $code, $fh0) = @_;

    my $call_code = sub {
        my ($ts, $content) = @_;
        package main {
            local $_ = $content;
            local $main::TS = $ts;
            local $main::PRINT = 1;
            $code->();
            if (!defined($main::TS)) {
                undef $ts;
            }
            if ($main::PRINT) {
                print "#$ts\n" if defined $ts;
                print;
            }
        }
    };

    my $fh;
    if ($which eq 'each_hist') {
        $fh = \*ARGV;
    } else {
        $fh = $fh0;
    }

    my $ts;
    while (defined(my $line = <$fh>)) {
        if ($line =~ /\A#(\d+)$/) {
            $ts = $1;
        } else {
            $call_code->($ts, $line);
            undef $ts;
        }
    }
}

sub each_hist(&) {
    my $code = shift;
    _doit('each_hist', $code);
}

sub parse_bash_history_file {
    my ($path) = @_;

    $path //= $ENV{HISTFILE} // "$ENV{HOME}/.bash_history";

    open my($fh), "<", $path or die "Can't open bash history file '$path': $!";
    my $res = [];
    _doit('parse_bash_history_file',
          sub {
              push @$res, [$main::TS, $_];
              $main::PRINT = 0;
          },
          $fh,
      );
    $res;
}

1;
# ABSTRACT: Utility to read bash history file entries

__END__