File Coverage

lib/Badger/Log/File.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	7	10	70.0
condition	7	10	70.0
subroutine	11	11	100.0
pod	9	9	100.0
total	73	79	92.4

#========================================================================
#
# Badger::Log::File
#
# DESCRIPTION
#   Subclass of Badger::Log for logging messages to a file.
#
# AUTHOR
#   Andy Wardley
#
#========================================================================

package Badger::Log::File;

use Badger::Class
    version    => 0.02,
    base       => 'Badger::Log',
    filesystem => 'FS',
    utils      => 'Now',
    config     => [
        'filesystem|method:FS',
        'filename|class:FILENAME',
        'filename_format|class:FILENAME_FORMAT',
        'keep_open|class:KEEP_OPEN=0',
    ],
    messages  => {
        no_filename => 'No filename or filename_format specified for log file',
        started     => 'Started logging',
    };

our $FORMATS = {
    DATE    => '%Y-%m-%d',
    TIME    => '%H-%M-%S',
    YEAR    => '%Y',
    MONTH   => '%m',
    DAY     => '%d',
    HOURS   => '%H',
    MINUTES => '%M',
    SECONDS => '%S',
};

sub init {
    my ($self, $config) = @_;
    $self->init_log($config);
    $self->init_file($config);
    return $self;
}

sub init_file {
    my ($self, $config) = @_;

    # init_log() has already called configured() which will copy the filename
    # parameter into $self.  We don't make the filename parameter mandatory
    # in the config schema because that will report missing parameters
    # using error_msg() which has been redefined in Badger::Log.  So we
    # check for it here and use our "backdoor" _error_msg() method.
    return $self->_error_msg('no_filename')
        unless defined $self->{ filename }
            || defined $self->{ filename_format };

    # if filename is set but not filename_format then this is a no-op
    # as expand_filename() will return the filename
    $self->{ filename } = $self->expand_filename;

    $self->info_msg('started');
}

sub expand_filename {
    my $self     = shift;
    my $format   = $self->{ filename_format } || return $self->{ filename };
    my $strftime = $format;
    # expand any  markers to convert to strftime format
    $strftime =~ s/<(\w+)>/$FORMATS->{ $1 } || $1/ge;
    # now format using strftime
    return Now->format($strftime);
}

sub filename_changed {
    my $self     = shift;
    my $filename = $self->expand_filename;
    return $filename ne $self->{ filename }
        ? ($self->{ filename } = $filename)
        : undef;
}

sub file {
    my $self     = shift;
    my $filename = $self->{ filename };
    return ($self->{ file } = $self->{ filesystem }->file($filename));
}

sub filehandle {
    my $self = shift;
    if ($self->filename_changed) {
        $self->release;
    }
    return $self->acquire;
}

sub acquire {
    my $self = shift;

    # Badger::Filesystem::File::append() method returns file handle open for append
    return $self->{ handle }
        ||= $self->file->append;
}

sub release {
    my $self = shift;
    my $fh   = delete $self->{ handle } || return;
    $fh->close;
}


sub log {
    my ($self, $level, $message) = @_;
    my $handle = $self->filehandle;
    my $output = sprintf($self->format($level, $message));
    $output =~ s/\n+$//;
    $handle->printflush($output, "\n");

    $self->release unless $self->{ keep_open };
}


sub DESTROY {
    shift->release;
}


1;

__END__